For my Irrlicht projects I like referring to how some things were done in Blender..
Code: Select all
#version 120
#define PI 3.14159265 // Used?
uniform sampler2D Image01; // Image..
uniform sampler2D Image02; // Depth..
uniform float BufferWidth;
uniform float BufferHeight;
// From App when tweaks done..
// uniform float focalDepth; //focal distance value in meters, but you may use autofocus option below
// uniform float focalLength; //focal length in mm
// uniform float aperture; //pupil diameter in mm
// uniform int showFocus; //show debug focus point and focal range (red = focal point, green = focal range)
float focalDepth = 40.0; // RED focal distance value in meters, but you may use autofocus option below
float focalLength = 0.35; // GREEN (bigger is tighter) focal length in mm
float aperture = 1.5; //pupil diameter in mm
int showFocus = 0; // Not sure if Irrlicht sends these as BOOLS so I use INT..
float width = BufferWidth; //texture width
float height = BufferHeight; //texture height
vec2 texel = vec2(1.0 / width, 1.0 / height);
// Make sure that these two values are the same for your camera, otherwise distances will be wrong.
float znear = 0.05; //camera clipping start
float zfar = 200.0; //camera clipping end
//- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
//user variables
int samples = 3; // samples on the first ring
int rings = 4; // Was 4.. ring count
bool autofocus = true; // use autofocus in shader? disable if you use external focalDepth value
vec2 focus = vec2(0.5,0.5); // autofocus point on screen (0.0,0.0 - left lower corner, 1.0,1.0 - upper right)
float maxblur = 1.0; // clamp value of max blur (0.0 = no blur,1.0 default)
float threshold = 0.5; // highlight threshold;
float gain = 2.0; // highlight gain;
float bias = 0.5; // bokeh edge bias
float fringe = 0.7; // bokeh chromatic aberration/fringing
bool noise = false; // use noise instead of pattern for sample dithering
float namount = 0.0001; // dither amount
bool depthblur = false; // blur the depth buffer?
float dbsize = 1.25; // depthblursize
// next part is experimental
// not looking good with small sample and ring count
// looks okay starting from samples = 4, rings = 4
bool pentagon = false; //use pentagon as bokeh shape?
float feather = 0.4; //pentagon shape feather
//------------------------------------------
float penta(vec2 coords) //pentagonal shape
{float scale = float(rings) - 1.3;
vec4 HS0 = vec4( 1.0, 0.0, 0.0, 1.0);
vec4 HS1 = vec4( 0.309016994, 0.951056516, 0.0, 1.0);
vec4 HS2 = vec4(-0.809016994, 0.587785252, 0.0, 1.0);
vec4 HS3 = vec4(-0.809016994,-0.587785252, 0.0, 1.0);
vec4 HS4 = vec4( 0.309016994,-0.951056516, 0.0, 1.0);
vec4 HS5 = vec4( 0.0 ,0.0 , 1.0, 1.0);
vec4 one = vec4( 1.0 );
vec4 P = vec4((coords),vec2(scale, scale));
vec4 dist = vec4(0.0);
float inorout = -4.0;
dist.x = dot( P, HS0 );
dist.y = dot( P, HS1 );
dist.z = dot( P, HS2 );
dist.w = dot( P, HS3 );
dist = smoothstep( -feather, feather, dist );
inorout += dot( dist, one );
dist.x = dot( P, HS4 );
dist.y = HS5.w - abs( P.z );
dist = smoothstep( -feather, feather, dist );
inorout += dist.x;
return clamp( inorout, 0.0, 1.0 );
}
float bdepth(vec2 coords) //blurring depth
{float d = 0.0;
float kernel[9];
vec2 offset[9];
vec2 wh = vec2(texel.x, texel.y) * dbsize;
offset[0] = vec2(-wh.x,-wh.y);
offset[1] = vec2( 0.0, -wh.y);
offset[2] = vec2( wh.x -wh.y);
offset[3] = vec2(-wh.x, 0.0);
offset[4] = vec2( 0.0, 0.0);
offset[5] = vec2( wh.x, 0.0);
offset[6] = vec2(-wh.x, wh.y);
offset[7] = vec2( 0.0, wh.y);
offset[8] = vec2( wh.x, wh.y);
kernel[0] = 1.0/16.0; kernel[1] = 2.0/16.0; kernel[2] = 1.0/16.0;
kernel[3] = 2.0/16.0; kernel[4] = 4.0/16.0; kernel[5] = 2.0/16.0;
kernel[6] = 1.0/16.0; kernel[7] = 2.0/16.0; kernel[8] = 1.0/16.0;
for(int i = 0; i < 9; i++ )
{float tmp = texture2D(Image02, coords + offset[i]).r;
d += tmp * kernel[i];
}
return d;
}
vec3 color(vec2 coords,float blur) //processing the sample
{vec3 col = vec3(0.0);
col.r = texture2D(Image01,coords + vec2(0.0,1.0)*texel*fringe*blur).r;
col.g = texture2D(Image01,coords + vec2(-0.866,-0.5)*texel*fringe*blur).g;
col.b = texture2D(Image01,coords + vec2(0.866,-0.5)*texel*fringe*blur).b;
vec3 lumcoeff = vec3(0.299,0.587,0.114);
float lum = dot(col.rgb, lumcoeff);
float thresh = max((lum-threshold)*gain, 0.0);
return col+mix(vec3(0.0),col,thresh*blur);
}
vec2 rand(vec2 coord) //generating noise/pattern texture for dithering
{float noiseX = ((fract(1.0-coord.s*(width/2.0))*0.25)+(fract(coord.t*(height/2.0))*0.75))*2.0-1.0;
float noiseY = ((fract(1.0-coord.s*(width/2.0))*0.75)+(fract(coord.t*(height/2.0))*0.25))*2.0-1.0;
if (noise)
{noiseX = clamp(fract(sin(dot(coord ,vec2(12.9898,78.233))) * 43758.5453),0.0,1.0)*2.0-1.0;
noiseY = clamp(fract(sin(dot(coord ,vec2(12.9898,78.233)*2.0)) * 43758.5453),0.0,1.0)*2.0-1.0;
}
return vec2(noiseX,noiseY);
}
vec3 debugFocus(vec3 col, float blur)
{float m = smoothstep(0.0,0.01,blur);
float e = smoothstep(0.99,1.0,blur);
float ee = smoothstep(0.97,1.0,blur)-e;
col = mix(vec3(1.0,0.0,0.0),col,m);
col = mix(vec3(0.0,1.0,0.0),col,(1.0-ee)-(1.0-e)*0.1);
return col;
}
float linearize(float depth)
{return -zfar * znear / (depth * (zfar - znear) - zfar);
}
void main()
{float blur = 0.0;
float depth = linearize(texture2D(Image02,gl_TexCoord[0].xy).w); // IF YOU USE ALPHA MAKE SURE THIS KNOWS IT..
if (depthblur)
{depth = linearize(bdepth(gl_TexCoord[0].xy));
}
blur = abs(aperture * (focalLength * (depth - focalDepth)) /(depth * (focalDepth - focalLength)));
if (autofocus)
{float fDepth = linearize(texture2D(Image02,focus).w); // IF YOU USE ALPHA MAKE SURE THIS KNOWS IT..
blur = abs(aperture * (focalLength * (depth - fDepth)) /
(depth * (fDepth - focalLength)));
}
blur = clamp(blur,0.0,1.0);
vec2 noise = rand(gl_TexCoord[0].xy)*namount*blur;
float w = (1.0/width)*blur*maxblur+noise.x;
float h = (1.0/height)*blur*maxblur+noise.y;
vec3 col = texture2D(Image01, gl_TexCoord[0].xy).rgb;
float s = 1.0;
int ringsamples;
for (int i = 1; i <= rings; i += 1)
{ringsamples = i * samples;
for (int j = 0 ; j < ringsamples ; j += 1)
{float step = PI*2.0 / float(ringsamples);
float pw = (cos(float(j)*step)*float(i));
float ph = (sin(float(j)*step)*float(i));
float p = 1.0;
if (pentagon)
{p = penta(vec2(pw,ph));
}
col += color(gl_TexCoord[0].xy + vec2(pw*w,ph*h),blur)*mix(1.0,(float(i))/(float(rings)),bias)*p;
s += 1.0*mix(1.0,(float(i))/(float(rings)),bias)*p;
}
}
col /= s;
if (showFocus == 1)
{col = debugFocus(col, blur);
// col = vec4(1.0, 0.0 ,1.0, 1.0); // just checking..
}
// OVERRIDE FOCAL DEBUG VISUALISATION..
// col = debugFocus(col, blur);
gl_FragColor.rgb = col;
// gl_FragColor.rgb = vec3 (depth,depth,depth);
gl_FragColor.a = 1.0;
}
// END..